Clinchers

Contributed by Sanford

Written by Thunder Brothers:

Complete Fighter - Clincher (C)

Typical development for a 5'1" clincher fighting in super welter (153lbs). Main text by Thunder Brothers.
STATUS 0
A new fighter
STR 25 KP 0
SPD 13 AGL 7
CHN 9 CND 14

STATUS 6
Low regional
STR 29 KP 0
SPD 14 AGL 8
CHN 9 CND 15

STATUS 12
Middle regional
STR 33 KP 0
SPD 17 AGL 9
CHN 10 CND 15

STATUS 18
High regional
STR 38 KP 0
SPD 19 AGL 10
CHN 10 CND 16

STATUS 24
Middle contender
STR 41 KP 0
SPD 21 AGL 11
CHN 11 CND 17

CHAMPION
of the world
STR 45 KP 0
SPD 22 AGL 13
CHN 11 CND 17

Clinchers in short
Clinchers are typically four to five inches shorter than anyone else in the weight class except for maybe a freak flasher. Handled by a competent manager these fighters may lose the fight but will usually give the opponent 40-60 IPs for the pleasure of winning. A good clincher will always leave his mark Some well-known clincher managers are; Shinra, Uncle Kewari, Simon Gagnon and of course Monk. They seldom win world titles but are fun and easy to manage.

Clincher design
For the moment I recommend that any fighter should have low Cuts. Clincher should generally be created with Very Heavy Build but a Very Light clincher will offset some of his opponents height advantage and will make some managers under estimate you strength. A clincher lives and dies by his tremendous STR, but SPD should not be forgotten since it is part of the formula for endurance damage. The low AGL keeps them safe from the use of ropes and to some extent counter. They can be made with AGL as low as 1-3 but then they are classed as Freak Clinchers. Should AGL due to randoms APs or training rise to about equal to SPD he will have turned into a Slugger. Since AGL gains from 9-11 causes a huge drop in weight it is very difficult to stay in the same weight class for the whole career, so dont create them in a too low weight. They are hard to wear down but the low AGL gives the trouble versus almost any kind of KP-fighter. But a point or two extra CHN allows them to pound those pesky KP-Dancers to oblivion...

Favourite opponent
Most non-kp that lack sufficient STR will fear a clincher; Dancer, Sissy, and even Balanced fighters. If CHN is good KP-Dancers will be easy prey as well.

Dreaded opponent
Anyone with more than 4KP is a real threat; Flashers, KP-Balanced, KP-Sluggers. But Sluggers and Agile Sluggers have almost equal STR and are very difficult match-ups.

How to win with a clincher
Clinchers typically win by going to the body with 5B/7/8(clinch) for 8-9 rounds and then target head with 5H/9/6(inside) when the opponent is too worn down to defend himself. They main thing is to build up as huge endurance advantage as you possibly can before you knock him out. You will seldom win on points. Stealing a round or two with 6/6/8(clinch) or even 7/5/8(clinch) will cause the opponent to worry about both score and endurance.

How to beat a clincher
If you have any sort of decent STR 4B/8/8 or even 3B/9/8 ring or counter is you best bet. If you need to score - open up to 5B/5/10 or 5B/6/9. Don't back away too much with lines like 3B/5/12, because he might score a round and will build up his endurance advantage as well. If you have KP, flash him early and flash him hard, just make sure he is targeting body while you do it. If you are a dancer use as high DEF as you can while still winning rounds, most likely 4/1/15(ring). If he has low CHN a 5H/11!/4(counter) may win you the fight, even if you lose you only take 25 IPs which is better that going the full distance.

Want to know more?
Check out these great pages as well:

* Albino's match-up help for Clinchers
* Unforgiven's Clincher 1 and several fight plans on the main page
* Bad Bit and WILBOO Inc's Newbie Help Files! has a section on clinchers

Instant Fight Plans®
(Not instant yet, you will have to Cut&Paste for the time being)
The plans below are given as they are. I give no guarantees apart from the fact that I have used them several times
#########################################
# Thunder Brothers - Clincher - Bash & KO
#
# A fairly standard clincher plan
# Maybe the stun/flash attempts should be
# removed or toned down
#1.0#050606##############################

# Early rounds
1) 5B/8/7 (clinch);
# Pound harder if I take no damage
if endurance_percent > 100 - (round - 1) * 3 then 4B/8/8 (inside);
if endurance_percent > 100 - (round - 1) * 2 then 4B/9/7 (inside);
if endurance_percent > 100 - (round - 1) * 1 then 5B/9/6 (inside);

# Middle rounds
5) 5B/7/8 (clinch);
# Pound harder if I take little or no damage
if endurance_percent > 100 - (round - 1) * 4 then 5B/8/7 (clinch);
if endurance_percent > 100 - (round - 1) * 3 then 4B/8/8 (inside);
if endurance_percent > 100 - (round - 1) * 2 then 4B/8/7 (inside);

# Time to check the score so it doesn't get out of hand
if score < 0 then 6B/7/7 (clinch);
if score < -1 then 8/6/6 (clinch);

# Pound even harder if he is getting tired
if opp < 2 and endurance_percent > 75 then 5B/10/5 (inside);
if opp < 2 and endurance_percent > 85 then 5B/11/4 (inside);
if opp < 2 and endurance_percent > 92 and mystuns = 0 then 5B/10/5 (allout);

# Rest & flash, remember to change the rounds once in a while
if round = 7 and endurance_percent < 75 then 2/1/8 (clinch);
if round = 8 then 6H/11!/3 (clinch);

# Late rounds
9) 6B/7/7 (clinch);
if score < 1 then 8/6/6 (clinch);
if score < 0 then 10/4/6 (clinch);
if score < round - 10 then 10/4/6 (clinch);
if score < round - 11 then 12/2/6 (inside);
if score < round - 12 then 5H/11/4 (inside);
if score < round - 12 and endurance_percent > 90 then 5H/11/4 (allout);
if score < round - 14 then 5B/10/5 (inside);

# Last round
12) 11/3/6 (clinch);
if score > 1 then 6/7/7 (clinch);
if score = 1 then 9/4/7 (clinch);
if score = -1 then 6H/11/3 (inside);
if score = -1 and endurance_percent > 85 then 5H/11/4 (allout);

# Global conditions - always valid
# Try for a stun/knockdown
1) if opponent = tired and endurance_percent > 80 and mystuns + hisstuns = 0 then 4H/9/7 (inside);
# He is dead on his feet finish him off
1) if opponent = weak and endurance_percent > 60 then 5H/10/5 (inside);
# I'm loosing badly, give up
1) if endurance_percent < 50 and opp > score then towel;
# I've won
1) if score > 14-round then 5B/7/8 (clinch);
# Cheat if we can...
1) if score < 13-round and warnings=0 then cheat;

#########################################################
# Thunder Brothers - Clincher - Power scoring vs Balanced
#
# A clinch plan that tries to force the opponent to open up
# by using fairly high aggression in the beginning and
# only pounds really hard when ahead and the opponent
# hopefully is opening up to catch up on score.
#1.0#050606###############################################

# Early rounds
1) 6/6/8 (clinch);

# Drop body, increase AGG and try to score if he hits back hard enough
if endurance_percent * 2 < 208 - 8 * round then 7/5/8 (clinch);

# Increase AGG if I take no or little damage, don't let him get away
if endurance_percent * 2 > 208 - 8 * round then 6B/7/7 (clinch);
if endurance_percent * 2 > 207 - 7 * round then 7B/7/6 (clinch);
if endurance_percent * 2 > 206 - 6 * round then 8/6/6 (clinch);
if endurance_percent * 2 > 205 - 5 * round then 9/6/5 (clinch);
if endurance_percent * 2 > 204 - 4 * round then 10/5/5 (clinch);

# Punish him when he tries to catch up but keep AGG up so
# that he will have to open up if he wants the round
if score > 0 then 6B/6/8 (inside);
if score > 0 and endurance_percent * 2 < 207 - 7 * round then 6B/6/8 (clinch);

# Middle and late rounds
5)
# Pound if the score> -1 when he is fresh and
# when score >-2 when i he is getting tired
if score > opp-3 and endurance_percent < 104 - 4 * round then 4B/8/8 (clinch);
if score > opp-3 and endurance_percent >= 104 - 4 * round then 5B/7/8 (clinch);
if score > opp-3 and endurance_percent > 103 - 3 * round then 5B/8/7 (clinch);
if score > opp-3 and endurance_percent * 2 > 205 - 5 * round then 5B/7/8 (inside);
if score > opp-3 and endurance_percent > 102 - 2 * round then 5B/8/7 (inside);
if score > opp-3 and endurance_percent > 101 - 1 * round then 5B/9/6 (inside);

# Try for stun/knockdown when score is close and he is tired
if roundslost+1 = roundswon and opp<2 and mystuns = 0 then 5H/11/4 (inside);

# Safeguards if score is slipping away and he is still fresh
if score < round - 10 and opp = 2 then 10/3/7 (clinch);
if score < round - 10 and opp = 2 and endurance_percent * 2 > 207 - 7 * round then 12/1/7 (outside);
if score < round - 12 then 6H/11/3 (clinch);
if score < round - 12 and endurance_percent * 2 > 205 - 5 * round then 5H/10/5 (inside);

# Rest - remember to change round once in a while
if endurance_percent < 77 and round = 8 then 2B/1/8 (clinch);

# Last round - secure victory
12) 5H/11/4 (inside);
if endurance_percent < (opp + 1) * 33 then 5H/7/8 (clinch);
if score > 1 then 7/5/8 (clinch);
if score > 1 and endurance_percent < (opp + 1) * 33 then 4H/6/10(clinch);
if score = 1 then 4H/9/7 (inside);
if score = 1 and endurance_percent < (opp + 1) * 33 then 5H/10/5 (feint);
if score <= -1 then 6H/11/3 (inside);
if score <= -1 and endurance_percent > 85 then 5H/11/4 (allout);

# Global conditions - always valid
# Stun-o-meter
1) if 2 * (mystuns - hisstuns) > round then 5H/6/9 (clinch);
# He is dead on his feet finish him off
1) if opp = 0 and endurance_percent > 60 and score > 1 then 5H/10/5 (inside);
# I'm loosing badly, give up
1) if endurance_percent < 50 and opp > score then towel;
# I've won, protect against flash attempt
1) if score > 14-round then 4H/8/8 (clinch);

##########################################################
# Thunder Brothers - Clincher - Power scoring vs KP-Dancer
#
# A clinch plan that tries to force the opponent to open up
# by using fairly high aggression in the beginning and
# only pounds really hard when ahead and the opponent
# hopefully is opening up to catch up on score.
# Some extra score conditionals for the middle and late
# rounds, we can't afford to let him too far ahead on score
# The DEF values should be adjusted so that a flash with
# 5H/11/4(counter) at best scores a knockdown while he is
# fresh
#1.0#050606###############################################

# Early rounds
1) 5B/9/6 (clinch);
# Increase AGG but keep DEF up if he backs off
if endurance_percent < 106 - round * 6 then 5B/8/7 (clinch);
if endurance_percent > 104 - round * 4 then 6B/8/6 (clinch);
if endurance_percent > 103 - round * 3 then 7/7/6 (clinch);
if endurance_percent > 102 - round * 2 then 8/6/6 (clinch);

# Pound away with good DEF if up on score
if score > 2 - opp then 4B/8/8 (clinch);
if score > 2 - opp and endurance_percent > 104 - round * 4 then 5B/8/7 (clinch);
if score > 2 - opp and endurance_percent > 102 - round * 2 then 6B/8/6 (clinch);

# Pound even harder if he is getting tired
if opp * 33 + 35 < endurance_percent then 4B/10/6 (clinch);
if opp * 33 + 40 < endurance_percent then 5B/10/5 (clinch);
if opp * 33 + 45 < endurance_percent then 5B/11/4 (clinch);
if opp * 33 + 50 < endurance_percent then 6B/11/3 (clinch);

# A sneaky flash if he has gotten tired while going for score
if endurance_percent * 2 > 205 - 5 * round and score < 0 - opp and mystuns = 0 and opp < 2 then 6H/11/3 (clinch);

# Rest hard if I must
if endurance_percent < 70 then 2B/1/5 (clinch);

# Middle rounds
# Keep an eye on the score
5) if score < -3 and score > -6 and opp < 2 then 6/9/5 (clinch);
7) if score < -2 and score > -5 and opp < 2 then 8/7/5 (clinch);
9) if score < -1 and score > -4 and opp < 2 then 9/6/5 (clinch);

# Flash him if I'm up on score
if score > 0 then 5H/10/5 (inside);
if score > 0 and endurance_percent * 2 > 205 - 5 * round then 6H/10/4 (allout);
if score > 0 and mystuns = 0 then 6H/11/3 (inside);

# Rest hard if I must
if score < 0 and endurance_percent < 70 then 2B/1/5 (clinch);

# Last round
12) 11/3/6 (clinch);
if score > 1 then 5H/7/8 (clinch);
if score = 1 then 10/3/7 (clinch);
if score >= 0 and endurance_percent + 8 > (opp + 1) * 33 then 5H/11/4 (inside);
if score <= -1 then 5H/10!/5 (allout);
if score <= -1 and endurance_percent > 85 then 6H/11!/3 (allout);

# Global conditions - always valid
# He is dead on his feet finish him off
1) if opp = 0 and endurance_percent > 60 then 5H/10/5 (inside);
# He is trying to run away on score, get him!
1) if score < round - 13 and mystuns + hisstuns = 0 then 6H/11!/3 (clinch);
# I've won, protect against flash attempt
1) if score > 15 - round then 4H/6/10 (clinch);
# I'm loosing badly, give up
1) if endurance_percent < 50 and opp > score then towel;
# Cheat if I have to
1) if warnings = 0 and (score < 0 or opp<2) then cheat;