Agile Slugger

Contributed by Sanford

Written by The Hole and Thunder Brothers

The Hole's Agile Slugger Fight Plan Decision Maker

The basic Fp template
Watch it change and grow with every decision you make

#opening line
1) 4b/8/8

#early rounds--doing damage
2) 4B/7/9
if endurance_percent > 100 - (round - 1) * 5 and mystuns <= 1 then 5B/8/7 (clinch);
if endurance_percent > 100 - (round - 1) * 5 and mystuns <= 1 and score<0 then 7/6/7 (feint);
if endurance_percent > 100 - (round - 1) * 4 and mystuns <= 1 then 5B/8/7 (inside);
if endurance_percent > 100 - (round - 1) * 4 and mystuns <= 1 then 7/6/7 (inside);
if 2 * endurance_percent > 200 - (round - 1) * 7 and mystuns = 0 then 5B/9/6 (inside);
if endurance_percent > 100 - (round - 1) * 3 and mystuns = 0 then 5B/9/6 (inside);
if 2 * endurance_percent > 200 - (round - 1) * 5 and round > 3 and mystuns = 0 then 5B/10/5 (inside);
if score >= round - 10 and warnings = 0 then cheat;

#slipping behind on points--speed up
if score < round - 9 then 6/5/9 (feint);
if mystuns > 2 and score < round - 9 then 6/5/9 (ring);
if endurance_percent > 100 - (round - 1) * 5 and mystuns = 0 and score < round - 9 then 6/7/7 (clinch);
if endurance_percent > 100 - (round - 1) * 4 and mystuns = 0 and score < round - 9 then 6/7/7 (feint);
if 2 * endurance_percent > 200 - (round - 1) * 7 and mystuns = 0 and score < round - 9 then 6/7/7 (inside);
if endurance_percent > 100 - (round - 1) * 3 and mystuns = 0 and score < round - 9 then 6/8/6 (inside);
if 2 * endurance_percent > 200 - (round - 1) * 5 and mystuns = 0 and score < round - 9 then 7/8/5 (inside);

#on the verge of losing on points--speed up more
if score < round - 11 then 11/1/8 (clinch);
if mystuns > 2 and score < round - 11 then 7/6/7 (ring);
if endurance_percent > 100 - (round - 1) * 5 and mystuns = 0 and score < round - 11 then 11/1/8 (feint);
if endurance_percent > 100 - (round - 1) * 4 and mystuns = 0 and score < round - 11 then 12/1/7 (feint);
if endurance_percent > 100 - (round - 1) * 3 and mystuns = 0 and score < round - 11 then 13/1/6 (feint);
if 2 * endurance_percent > 200 - (round - 1) * 5 and mystuns = 0 and score < round - 11 then 10/5/5 (feint);

#lost on points--time for desparate tactics
if score < round - 12 then 5H/10/5 (inside);
if mystuns > 3 then 5H/9/6 (clinch);

if endurance_percent > 100 - (round - 1) * 5 and mystuns = 0 and score < round - 12 then 5H/9/6 (inside);
if endurance_percent > 100 - (round - 1) * 4 and mystuns = 0 and score < round - 12 then 5H/10/5 (inside);

if endurance_percent > 100 - (round - 1) * 3 and mystuns = 0 and score < round - 12 then 6H/10/4 (inside);
if score < round - 12 and warnings = 0 then cheat;
if score < round - 13 and round > 11 and warnings < 2 then cheat;

#rest if needed and ahead in score
if score > 0 and endurance_percent < 100 - (round - 1) * 5 then 1/1/8;
if score > 14 - round then 4H/8/8 (clinch);
if score >= 14 - round and endurance_percent < 100 - (round - 1) * 5 and opp = 2 then 1/1/18 (outside);

8) if score > 0 and endurance_percent < 100 - (round - 1) * 4 then 1/1/8 (clinch);

if score > 1 and endurance_percent < 100 - (round - 1) * 3 and opp = 2 then 1/1/8 (clinch);

#Endgame
10) 12/1/7 (feint);
if score < 1 then 13/1/6 (feint);
if mystuns > 2 then 12/1/7 (ring);
if mystuns = 0 and score <= 14 - round and endurance_percent > 80 and mystuns = 0 and opp <= 1 then 13/1/6 (feint);
if mystuns = 0 and score <= 14 - round and mystuns = 0 and opp = 0 then 13/1/6 (feint);
if score > 0 and round = 10 then 5/9/6 (inside);
if score > 1 and round = 11 then 5/9/6 (inside)
if score > 1 and endurance_percent < 80 then 6/7/7 (inside);
if score > 1 and (endurance_percent < 70 or mystuns > 0) then 7/5/8 (feint);
if score > 1 and opp = 0 then 5H/10/5 (inside);
if score > 2 then 5H/8/7 (inside);
if score > 2 and opp = 0 then 5H/9/6 (allout);

if endurance_percent > 100 - (round - 1) * 4 and mystuns = 0 and score < round - 12 and hisstuns > 1 then 5H/10/5 (inside);
if endurance_percent > 100 - (round - 1) * 3 and opp = 0 and score > 2 then 5H/10/5 (inside);
if score < round - 12 and warnings = 0 then cheat;
if score < round - 14 and round >= 11 and warnings < 2 then cheat;
if score > 15 - round then 4H/8/8 (clinch);
if score > 14 - round and endurance_percent < 75 and mystuns > 0 then 4H/8/8 (clinch);
if round = 10 and score > 1 and endurance_percent < 100 - (round - 1) * 5 then 1/1/8 (clinch);
if score < -1 and endurance_percent < 50 then towel;



Written by Thunder Brothers:

Complete Fighter - Agile Slugger (AS)

Typical development for a 5'7" Agile Slugger fighting in super welter (153lbs). Main text by Thunder Brothers

STATUS 0
A new fighter
STR 15 KP 0
SPD 9 AGL 15
CHN 9 CND 14

STATUS 6
Low regional
STR 17 KP 0
SPD 11 AGL 17
CHN 9 CND 15

STATUS 12
Middle regional
STR 21 KP 0
SPD 13 AGL 19
CHN 10 CND 15

STATUS 18
High regional
STR 24 KP 0
SPD 15 AGL 22
CHN 10 CND 16

STATUS 24
Middle contender
STR 26 KP 0
SPD 17 AGL 25
CHN 11 CND 17

CHAMPION
of the world
STR 29 KP 0
SPD 18 AGL 27
CHN 11 CND 17

Agile Sluggers in short
Sluggers seems to be the fighter type where the greatest confusion reigns. Everyone agrees that the are strong and dish out IPs freely and at times have difficulty winning on score. AS are the best endurance fighters around and rule Bare Knuckles where endurance is everything. With the recent changes to clinch they have become viable again. Ring, clinch and inside are the styles of choice and preferred strategies are Bash & KO and Bash & Run.

Agile Slugger design
This is a common variety of slugger. Depending on the managers preferences they range from having STR = AGL+5 and AGL=SPD to STR=AGL=SPD+5. Some even claim that an Agile Slugger can have AGL>STR. A common variant has STR>AGL>SDP. The variant I like best has STR=AGL and SDP at 60-75% of STR. I usually create them at the same height as Balanced fighter at that weight. This means that when I get bored with just dealing out IPs I can start training SPD and will fairly soon have a Balanced fighter instead.

Favourite opponent
Clinchers are usually an easy win, 4B/8/8(ring) the whole fight is often enough but both will carry scars away from the fight and the clincher the lion's share of it. Against 0KP dancers his AGL will allow him go hard to the body with inside from the start.

Dreaded opponent
If CHN is low high KP fighters can be dangerous. Balanced fighters with good SPD can be a nightmare if handled by a good manager. KP-Dancers can be real tricky if CHN is too low, really poor SPD can also force you to open up too much when trying to catch up on score

How to win with Agile Sluggers
You win fights on your superior endurance efficiency. Wear him down and knock him out or run for score. Lines like 4B/8/8(ring) and 5B/7/8(ring) are your best friends and you will use them for most of the rounds in most of the fights. Throw in a few 6/6/8, 7/6/7 or 8/6/6 when you need to steal few rounds, it will force your opponent to open up when he takes those rounds back. An Agile Slugger should never slap with 1POW unless it is late in the fight and the opponent is very tired. Scoring is not your strong point. Against slightly taller and fast opponents clinch is a useful style since your STR advantage will be greater that your AGL advantage.

How to beat Agile Sluggers
Don't let him wear you down or knock him out early. If you are equally tall or just slightly taller but with better SPD it is vital to use as efficient tactics as possible while still winning the rounds, 4B/7/9 or 5B/6/9 should work well.

Want to know more?
Check out these great pages as well:

* Albino has stats and a fight plan on his Getting started page.
* Bad Bit and WILBOO Inc has a section on Agile Slugger at his Newbie Help Files.

Instant Fight Plans®
(Not instant yet, you will have to Cut&Paste for the time being)
The plans below are given as they are. I give no guarantees apart from the fact that I have used them several times

Albinos Agile Slugger Plan is very likely one of the most well-used plans in WeBL. It is a good plan but you should learn to recognize it when scouting and make sure that you have plans that can beat it. Albino has also posted a very similar plan without comments at his Getting Started - a method to instant success - page.
############################
#ALBINO - AGILE SLUGGER PLAN
############################

# start efficiently to the body
1) 5B/7/8 (ring);

# not taking much damage - open up a little
if endurance_percent > 100 - (round - 1) * 3 then 5B/7/8 (inside);

# only taking a little damage - open up a bit more
if endurance_percent > 100 - (round - 1) * 2 then 5B/8/7 (inside);

# hardly taking any damage - open up a lot
if endurance_percent > 100 - (round - 1) * 1 then 5B/9/6 (inside);

# if the ref hasn't warned you - cheat
if warnings = 0 then cheat;

# efficiently to the body
5) 5B/7/8 (inside);

# taking a fair bit of damage - use ring instead
if endurance_percent < 100 - (round - 1) * 4 then 5B/7/8 (ring);

# only taking a little damage - open up a bit
if endurance_percent > 100 - (round - 1) * 3 then 5B/8/7 (inside);

# hardly taking any damage - open up a lot
if endurance_percent > 100 - (round - 1) * 2 then 5B/10/5 (inside);

# if the ref hasn't warned you - cheat
if warnings = 0 then cheat;

# losing - use an extra point of AGG
if score < 0 then 6B/7/7 (ring);

# losing by a bit - try an win round while using decent POW
if score < -1 then 8/6/6 (ring);

# opponent is tired and you are 'still standing' - open up a lot
if opp < 2 and endurance_percent > 75 then 5B/10/5 (inside);

# opponent is tired and you 'don't need to rest' - open up a heaps.
# (only use this if opponent has 0 KP.)
if opp < 2 and endurance_percent > 85 then 5B/11/4 (inside);

# opponent is tired and you 'don't need to rest' - open up a LOTS.
if opp < 2 and endurance_percent > 92 and mystuns = 0 then 5B/10/5 (allout);

# you are tired - rest
if round = 8 and endurance_percent < 70 then 1/1/8 (clinch);

# opponent should be tired by now - keep to the body but 6 AGG could win rounds
9) 6B/7/7 (ring);

# losing or even score - try win rounds with decent POW
if score < 1 then 8/6/6 (ring);

# losing - try win rounds
if score < 0 then 10/4/6 (ring);

# can only afford to drop one round and still win - try win rounds
if score < round - 10 then 10/4/6 (ring);

# can't afford to drop any rounds and still win - try win rounds aggressively
if score < round - 11 then 13/1/6 (outside);

# winning remaining rounds gets a draw - try for KD in increment score by 2
if score < round - 12 then 5H/11!/4 (inside);

# same as above but you 'don't need to rest' - allout then, you may get a KO
if score < round - 12 and endurance_percent > 90 then 5H/11!/4 (allout);

# you have lost - try wear him down more (KO him later)
if score < round - 14 then 5B/10/5 (inside);

# score = 0 - win round
12) 11/3/6 (ring);

# good lead - make sure you can't get KO'd or KD'd
if score > 1 then 6/7/7 (ring);

# small lead - draw or better the round
if score = 1 then 9/4/7 (ring);

# small deficit - go for KD
if score < 0 then 6H/11/3 (inside);

# same as above but you 'don't need to rest' - allout then, you may get a KO
if score < 0 and endurance_percent > 85 then 5H/11/4 (allout);

# you can't win on points, may as well cheat
if score < -1 then cheat;

# you are very tired and the opponent is also not weak - give up
1)if opponent = strong and endurance_percent < 50 and score < 0 then towel;

# you have won - keep trying to hurt him
1)if score > 14 - round then 5B/7/8 (clinch);

# he is weak and you are strong or barely tired - KD or KO him,
# doesn't matter really, he can't hurt you
1)if opp = 0 and endurance_percent > 60 then 5H/10/5 (inside);

# You might have a chance at a draw if you can hang on.
1)if endurance_percent < 50 and opp = 2 and score > 12 - round then 1/1/18 (ring);

stop

# NOTE1:if AGG > POW then use opportunistic fighting or 'best openings' as the easy FP creator describes it.

# NOTE2: 4/8/8 is most efficient damage dealt/received ratio.

# NOTE3: when POW = 2 * AGG, it is efficient use of those energy points for dealing damage.
# 3/6/11, 5/10/5, 6/11/3 are quite popular

# NOTE4:if he's tired, i use more power, on the line below it, it checks my endurance,
# if i have only small advantage, i return to going efficient.

# NOTE5: dancing with 1 POW can be dangerous, scout your opponent,if you think he might use allout,
# set POW to AGG/2 or make them even. e.g. 6/3/11 or 8/4/8. e.g. 2 5/5/10 or 6/6/8 -
# only use these if STR > 9 and/or kp > 3 otherwise you are wasting you time so just use 5/1/14

# NOTE6: outside can be used by shorter fighters who are dancing to obtain +0.5 SPD and +0.5 AGL.
# clinch can be used similarly for resting (+1 AGL with no penalty).
# ring however gives +1 fatigue and pretty much cancels out +1 AGL bonus.


#-Thunder Brothers-#########################
#
# Agile Slugger vs Balanced
# Opponent is the same height or 1-2 inches taller
# but has better SPD
#
# This plan uses endurance conditionals
# to determine the level of effort. The more
# the opponent backs off the harder we pound
# until he gets tired
#
#1.1#050614#################################

# Start off with good power and decent score
1) 6B/7/7 (clinch);
2) 6B/7/7 (clinch);
# Drop AGG if tired but keep POW up to hurt him
if endurance_percent * 2 < 209 - 9 * round then 3B/9/8 (clinch);
# Go harder if he backs off to much
if endurance_percent * 2 > 208 - 8 * round then 5B/8/7 (clinch);
if endurance_percent * 2 > 207 - 7 * round then 5B/9/6 (clinch);
if endurance_percent * 2 > 206 - 6 * round then 5B/10/5 (clinch);
if endurance_percent * 2 > 205 - 5 * round then 5B/11/4 (clinch);

# Essentially the same block as above but switch to inside
# when he is tired.
if opp < 2 then 6B/7/7 (inside);
if opp < 2 and endurance_percent * 2 < 209 - 9 * round then 3B/9/8 (inside);
if opp < 2 and endurance_percent * 2 > 208 - 8 * round then 5B/8/7 (inside);
if opp < 2 and endurance_percent * 2 > 207 - 7 * round then 5B/9/6 (inside);
if opp < 2 and endurance_percent * 2 > 206 - 5 * round then 5B/10/5 (inside);
if opp < 2 and endurance_percent * 2 > 205 - 5 * round then 5B/11/4 (inside);

# Try to take advantage if he gets cut.
if opp < 2 and hiscuts > 4 then 5C/8/7 (inside);
if opp < 2 and hiscuts > 4 and endurance_percent * 2 > 208 - 8 * round then 5C/9/6 (inside);
if opp < 2 and hiscuts > 4 and endurance_percent * 2 > 207 - 7 * round then 4C/10/6 (inside);
if opp < 2 and hiscuts > 4 and endurance_percent * 2 > 206 - 6 * round then 5C/10/5 (inside);
if opp < 2 and hiscuts > 4 and endurance_percent * 2 > 205 - 5 * round then 5C/11/4 (inside);

# Stun/KO when he is tired and I`m feeling OK.
if opp < 2 and mystuns + hisstuns = 0 and endurance_percent > 104 - 4 * round then 5H/10/5 (inside);
# Stun/KO if he is winning the endurance battle
if opp = 2 and endurance_percent < 67 and endurance_percent > 60 and mystuns = 0 then 5H/11/4 (inside);
# Stun/KO if his lead is growing big and I haven`t managed to knock him down
if (round - score) > 9 and mystuns = 0 and hisknockdowns = 0 then 5H/10/5 (inside);

# Get some rest unless far behind
if endurance_percent < 75 and score > -2 and round < 10 then 2/1/8 (clinch);

9)
# Basic tactic is to KO him
if opp < 2 and mystuns = 0 then 5H/11/4 (inside);
if opp < 2 and mystuns = 0 and hisknockdowns = 0 and endurance_percent > 104 - 4 * round then 6H/11/3 (inside);
# Try to even the score if not too far behind
if opp < 2 and score < 0 and score > -3 then 6B/7/7 (inside);
if opp < 2 and score < 0 and score > -3 and endurance_percent * 2 < 208 - 8 * round then 6B/7/7 (clinch);
if opp < 2 and roundswon - roundslost < score and score > -3 then 6/7/7 (inside);

# Basic tactic is still the KO
11) 5H/11/4 (inside);
# Go for points if ahead
if score > 1 then 7/5/8 (ring);
# Rest if ahead and tired, KO next round instead
if score > 1 and endurance_percent < 70 then 1/1/8 (clinch);
# Try to even the score if not too far behind
if score < 1 and score > -2 then 8/3/9 (outside);

# KO to win
12) 6H/11/3 (inside);
# I`m too tired to flash, try for score
if score >= 0 and opp * 33 + 35 > endurance_percent then 7/4/9 (ring);
# Fight is close, try to draw.
if score < 0 and score > -2 then 13/1/6 (ring);

# Global
1)
# I've won, wait for the end of the fight
if score > 14 - round then 4B/8/8 (clinch);
# He's gone, take him out
if opp = 0 and endurance_percent > 60 then 5H/10/5 (inside);
# I'm loosing badly, give up
if opp > score and endurance_percent<50 then towel;

I've used this plan for a very long time and if the scouting is correct, it can't lose. The fight usually ends with KO in round 7. Use it and use it well!
#-Thunder Brothers-#########################
#
# Agile Slugger vs Inside Dudes
# Opponent has equal HGT or is shorter and
# uses inside B/H with the same level of
# effort the whole fight
# This plan uses a simple score ladder to
# determine what tactics we need to start
# winning rounds and then just waits for him
# to get tired.
#
#1.0#050613#################################

# Start very defensively
1) 2B/3/15 (ring);

# Score Ladder - Open up slowly to win rounds
if score + 3 < round then 3B/4/13 (ring);
if score + 5 < round then 4B/5/11 (ring);
if score + 7 < round then 5B/6/9 (ring);
if score + 9 < round then 6/5/9 (ring);

# Start to wear him down when he gets tired
if opp * 33 + 34 < endurance_percent then 4B/7/9 (ring);
if opp * 33 + 44 < endurance_percent then 4B/8/8 (ring);
if opp * 33 + 54 < endurance_percent then 4B/9/7 (ring);

# Check score when he gets really tired
if opp * 33 + 44 < endurance_percent and score < 0 then 6B/7/7 (ring);

# If he gets stunned while we target body, switch to head
if hisstuns > mystuns then 4H/9/7 (ring);

# Some inside dudes flash when their score is -2
if score = 2 then 4H/6/10 (ring);

# Rest if we have to. Use 3AGG in case he rests as well
if score > 2 - opp and round = 9 and endurance_percent < 75 then 3B/1/8 (clinch);

# End game conditionals, Score with high DEF. Use 3POW to protect against allout
if score < round - 8 then 6/3/11 (ring);
if score < round - 10 then 7/3/10 (ring);
#If he still wins rounds, flash him
if score < round - 11 then 4H/10/6 (inside);
if score < round - 12 then 5H/11/4 (inside);
# Wear him down if he is winning on points
if score < round - 14 then 5B/10/5 (inside);

# Last round - secure the win
12) 11/3/6 (ring);
if score > 1 then 4H/7/9 (ring);
if score = 1 then 8/5/7 (ring);
if score < 0 then 5H/11/4 (inside);
if score < 0 and endurance_percent > 85 then 5H/11/4 (allout);
if score < -1 then cheat;

# Global
# Go for head if he knocked you down
1) if myknockdowns > 0 and round < 7 then 3H/6/11 (ring);
# I've lost - give up
1) if endurance_percent < 50 and opp > score then towel;
# I've won protect against flash
1) if score > 14 - round then 3H/4/13 (ring);
# He is finished - Stun or KD
1) if opp = 0 and endurance_percent > 65 and round < 11 then 4H/9/7 (inside);


Sample agile slugger fp by DTAHYAIO!:

1) 5B/7/8 (ring);
if round < 4 and endurance_percent > 101 - round then 5B/10/5 (allout);
if score < 0 then 6B/7/7 (ring);
if score < -1 then 7/5/8 (ring);

4) 5/7/8 (ring);
if roundslost > 1 then 7/5/8 (ring);
if roundslost > 3 and score < 0 then 9/4/7 (ring);
if score > 0 then 5B/7/8 (ring);
if opp < 2 and endurance_percent > 70 and score > round - 9 then 5B/8/7 (ring);

8) 6/6/8 (ring);
if score > 1 then 5B/7/8 (ring);
if score < 0 then 11/1/8 (outside);
if score < round - 11 then 5B/10/5 (ropes);

11) 12/1/7 (outside);
if score > 0 then 9/4/7 (ring);
if score > 1 then 5B/7/8 (ring);
if score > 1 and mystuns > 0 then 4H/8/8 (ring);
if score > 2 then 3H/5/12 (ring);
if score < 0 then 13/1/6 (outside);
if score < -1 then 5B/11/4 (ropes);

1) if warnings = 0 then cheat;
if endurance_percent < 75 and opp = 2 and round < 12 and score > round - 10 then 1/1/10 (outside);
if opp = 0 and endurance_percent > 50 and round < 11 then 5B/10/5 (ropes);
if opp = 0 and round > 10 then 5H/11/4 (inside);

12) if score > 2 then 3H/5/12 (ring);
if score = 2 then 5/7/8 (ring);
if score = 1 or score = -1 then 13/1/6 (outside);
if score = 0 then 5H/11/4 (inside);
if score < -1 then 5H/10!/5 (allout);

stop